;*********************************************************
;SAMPLE PROGRAM   9850-1.ASM (2313-11BASE)
;CPU　　AT90S2313-10    2002/JUL,29th. / BY JJ1ILR
;*********************************************************

;**** INDICATE INCLUDE FILE ****

.include "2313def.inc"

;**** regster set ****
.DEF	AR0	= R00
.DEF	AR1	= R01
.DEF	AR2	= R02
.DEF	AR3	= R03
.DEF	AR4	= R04
.DEF	AT0	= R05
.DEF	AT1	= R06
.DEF	AT2	= R07
.DEF	AT3	= R08
.DEF	AT4	= R09
.DEF	DAR0	= R10 
.DEF	DAR1	= R11
.DEF	DAR2	= R12
.DEF	DAT0	= R13
.DEF	DAT1	= R14
.DEF	DAT2	= R15
.DEF	B0	= R16
.DEF	B1	= R17
.DEF	B2	= R18
.DEF	B3	= R19
.DEF	B4	= R20
.DEF	DB0	= R21
.DEF	DB1	= R22
.DEF	DB2	= R23

.def	SUB	= R25		;SUB ADDRESS
.def	DATA	= R26		;FOR DATA REG
.def	TRFLAG	= R27		;MSB[STEP1,STEP0,B,OLD-B,RIT,TX,UP,DN]LSB
.def	TEMP	= R28		;TEMP REG
.def	DDS	= R29		;DDS REG
;	ZL=Z	= R30		;
;	ZH	   R31		;

;	STACK POINT	$DF
;	DDS SENT DATA SAVE $60-62
;	TRFLAG	OLD DATA SAVE $63 	
;****reset vector and interrupt vector set ****

	rjmp	RESET		; Reset handle
	rjmp	RESET		; Reset handle
	rjmp	RESET		; Timer 0 overflow handler
	rjmp	RESET		; Reset handle
 
RESET:	LDI	TEMP,$00	;$63= TRFLAG OLD DATA CLEAR
	LDI	ZL,$63
	ST	Z,TEMP
	LDI	DDS,$00		;DDS=CLEAR
	LDI	TEMP,$DF	;STACK POINT SET
	OUT	SPL,TEMP
	LDI	R31,$00		;ZH=CLEAR
	LDI	TRFLAG,$00	;TRFLAG CLEAR	

;*** LCD INIT ***
	RCALL	PINIT0
	RCALL	PINIT1		;PORT OUTPUT SET(TEMP-1)
	LDI	DATA,$50	;250uS*80=20mS
	rcall	TIMER		;(DATA,SUB-2)
INITLCD:	LDI	DATA,$3F	;INITAL DATA
	RCALL	LCD8SO		;LCD 8BIT OUT(DATA-2)
	LDI	DATA,$14	;250uS*20=5mS
	RCALL	TIMER		;(DATA,SUB-2)
	LDI	DATA,$3F
	RCALL	LCD8SO		;(DATA-2)
	LDI 	DATA,$01	;250uS
	RCALL	TIMER		;(DATA,SUB-2)
	LDI	DATA,$3F
	RCALL	LCD8SO		;(DATA-2)
	LDI	DATA,$01	;250uS
	RCALL	TIMER		;(DATA,SUB-2)
	LDI	DATA,$2F
	RCALL	LCD8SO		;(DATA-2)
	RCALL	BUSY		;(TEMP-2)
	LDI	DATA,$28	;2GYO,5*7
	RCALL	LCD4SO		;(DATA,SUB-2)
	rcall	busy		;(TEMP-2)
	LDI	DATA,$0C	;LCD ON NO-CURSOL,NO-BRINC
	RCALL	LCD4SO		;(DATA,SUB-2)
	
;*** DISP DATA INIT ***
	RCALL	MS
	RCALL	TENS
	RCALL	ILR 	

;*** FREQUENCY DATA INIT  ***
	LDI	DATA,$32	;200.00
	MOV	AR0,DATA
	LDI	DATA,$30
	MOV	AR1,DATA
	MOV	AR2,DATA
	MOV	AR3,DATA
	MOV	AR4,DATA
	MOV	B2,DATA
	MOV	B3,DATA
	MOV	B4,DATA
	LDI	DATA,$33
	MOV	B0,DATA
	LDI	DATA,$37
	MOV	B1,DATA	

;*** DDS DATA INIT ***
	LDI	DATA,$4F	;4F5880(200.00)
	MOV	DAR0,DATA
	LDI	DATA,$58
	MOV	DAR1,DATA
	LDI	DATA,$80
	MOV	DAR2,DATA

	LDI	DATA,$51	;51F090(370.00)
	MOV	DB0,DATA
	LDI	DATA,$F0
	MOV	DB1,DATA
	LDI	DATA,$90
	MOV	DB2,DATA

;*** T->R *** 	
	RCALL	TR

;*** AD9850 SERIAL MODE ***

	CBI	PORTD,0		;STB
	CBI	PORTB,7		;DATA
	CBI	PORTB,6		;SCK
	SBI	PORTB,6
	CBI	PORTB,6
	SBI	PORTD,0		;STB
	CBI	PORTD,0
		
	RJMP	DISPS

;****  ＭＡＩＮ ****

MAIN:
;*** wait *** for noize
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT	
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	rcall	WAIT
	
;***READ  SWITCH & DATA SET ***
	MOV	TEMP,TRFLAG
	ANDI	TEMP,$10
	IN	DATA,PIND	;BIT 4 IS VFO A FLAG [L]=VFO A
	SWAP	DATA
	ANDI	DATA,$E0	;BIT 4 IS CLEARED
	MOV	TRFLAG,DATA
	OR	TRFLAG,TEMP
	IN 	DATA,PINB
	ANDI	DATA,$0F
	OR	TRFLAG,DATA
	MOV	DATA,TRFLAG
	LDI	ZL,$63		;LOAD TRFLAG OLD DATA FROM $63
	LD	SUB,Z
	CP	SUB,TRFLAG
	BREQ	ROTARY	
	ST	Z,TRFLAG	;TRFLAG SAVE TO $63
	SBRC	TRFLAG,5
	RJMP	ABF1		;BIT 4 IS NOT CLEARED
	ANDI	DATA,$10
	CPI	DATA,$10
	BREQ	MSC		;HIGH
	RJMP	RIT
ABF1:	ANDI	DATA,$10
	CPI	DATA,$10
	BREQ	RIT

;*** M<->S CHANG ***
MSC:	LDI	ZL,$00
	LDI	SUB,$10
MSC1:	LD	DATA,Z
	ADD	ZL,SUB
	LD	TEMP,Z
	ST	Z,DATA
	SUB	ZL,SUB
	ST	Z,TEMP
	INC	ZL
	CPI	ZL,$05
	BRNE	MSC1
	LDI	ZL,$0A
	LDI	SUB,$0B
MSC2:	LD	DATA,Z
	ADD	ZL,SUB
	LD	TEMP,Z
	ST	Z,DATA
	SUB	ZL,SUB
	ST	Z,TEMP
	INC	ZL
	CPI	ZL,$0D
	BRNE	MSC2
	
	RCALL	TR

	MOV	DATA,TRFLAG
	ANDI	DATA,$20
	LSR	DATA
	ANDI	TRFLAG,$EF		;BIT 4 CLEARED
	OR	TRFLAG,DATA
	RJMP	DISPS

;*** RIT ON ***
RIT:	SBRC	TRFLAG,3	;BIT 3 CHECKED
	RJMP	RITON
	RCALL	MS
	RCALL	TR
	RJMP	ROTARY
RITON:	RCALL	RT
	RJMP	DISPR

;****  rotary encorder ****
ROTARY:	MOV	TEMP,TRFLAG
	ANDI	TEMP,$03
	CPI	TEMP,$00
	BREQ	OROT0		;OLD DATA ZERO
	CPI	TEMP,$01
	BREQ	OROT1		;OLD DATA ONE
	CPI	TEMP,$02
	BREQ	OROT2		;OLD DATA TWE

OROT3:	IN	DATA,PINB	;OLD DATA THREE
	ANDI	DATA,$03
	CPI	DATA,$03
	BREQ	ROT0
	CPI	DATA,$01
	BREQ	ROTDN
	CPI	DATA,$02
	BREQ	ROTUP
	RJMP	ROT0

OROT1:	IN	DATA,PINB	;OLD DATA ONE
	ANDI	DATA,$03
	CPI	DATA,$01
	BREQ	ROT0
	CPI	DATA,$02
	BREQ	ROT0
	CPI	DATA,$03
	BREQ	ROT0
	RJMP	ROTDN

OROT2:	IN	DATA,PINB	;OLD DATA TWE
	ANDI	DATA,$03
	CPI	DATA,$00
	BREQ	ROTUP
	CPI	DATA,$01
	BREQ	ROT0
	CPI	DATA,$02
	BREQ	ROT0
	RJMP	ROTDN

OROT0:	IN	DATA,PINB	;OLD DATA ZERO
	ANDI	DATA,$03
	CPI	DATA,$00
	BREQ	ROT0
	CPI	DATA,$01
	BREQ	ROTUP
	CPI	DATA,$02
	BREQ	ROTDN
	RJMP	ROT0

ROT0:	RJMP	MAIN

ROTUP:	RJMP	DATAUP		;UP COUNT

ROTDN:	RJMP	DATADN		;DOWN COUNT

;*** FREQ DATA UP ***
DATAUP:	LDI	ZL,$04
	MOV	DATA,TRFLAG	;STEP SET
	ANDI	DATA,$C0
	CPI	DATA,$C0
	BREQ	ST10
	CPI	DATA,$80
	BREQ	ST100
	CPI	DATA,$40
	BREQ	ST1K
	DEC	ZL		;10k
ST1K:	DEC	ZL		;1k
ST100:	DEC	ZL
ST10:	RJMP	DUPS

DATADN:	LDI	ZL,$04
	MOV	DATA,TRFLAG	;STEP SET
	ANDI	DATA,$C0
	CPI	DATA,$C0
	BREQ	ST10D
	CPI	DATA,$80
	BREQ	ST100D
	CPI	DATA,$40
	BREQ	ST1KD
	DEC	ZL
ST1KD:	DEC	ZL		;1K
ST100D:	DEC	ZL
ST10D:	RJMP	DDNS

;*** disp data up  ***
DUPS:	RCALL	DUP
	IN	DDS,SREG
	CPI	ZL,$FF
	BRNE	DUPS
	OUT	SREG,DDS
	BRCS	DN1MS		;1MHz DOWN
DUPS1:	RCALL	DDSUP		
	RJMP	DISP
DN1MS:	RCALL	DN1M
	RJMP	DUPS1
	
;*** disp data dn  ***
DDNS:	RCALL	DDN
	IN	DDS,SREG
	CPI	ZL,$FF
	BRNE	DDNS
	OUT	SREG,DDS
	BRCS	UP1MS		;1MHz UP
DDNS1:	RCALL	DDSDN	
	RJMP	DISP
UP1MS:	RCALL	UP1M
	RJMP	DDNS1

;*** disp data write ***
DISP:	SBRC	TRFLAG,3	;BIT 3 CHECKED
	RJMP	DISPR
	RJMP	DISPS

;*** DISP R***
DISPR:	RCALL	RT
	LDI	ZL,$05
	RJMP	DIS
	 
;*** DISP S ***
DISPS:	RCALL	MS
	LDI	ZL,$10

DIS:	RCALL	BUSY		;
	LDI	DATA,$C7	;2GYOUME ADDRESS SET
	RCALL	LCD4SO

	RCALL	DCALL

	INC	ZL
	RCALL	DCALL

	INC	ZL
	RCALL	DCALL

	LDI	DATA,$2E
	RCALL	BUSY
	RCALL	LCD4RO

	INC	ZL
	RCALL	DCALL

	INC	ZL
	RCALL	DCALL

;*** DISP M ***
DISPM:	RCALL	BUSY
	LDI	DATA,$87	;A FREQ ADDRESS SET
	RCALL	LCD4SO

	LDI	ZL,$00
	RCALL	DCALL

	INC	ZL
	RCALL	DCALL
	
	INC	ZL
	RCALL	DCALL

	LDI	DATA,$2E
	RCALL	BUSY
	RCALL	LCD4RO

	INC	ZL
	RCALL	DCALL

	INC	ZL
	RCALL	DCALL

;*** DDS DATA SEND ***	

;*** CHECK SENDING DATA ***

	MOV	TEMP,TRFLAG
	ANDI	TEMP,$08	;RIT FLAG
	CPI	TEMP,$08
	BREQ	DDSRIT		;RIT ON
	RJMP	DDSRX		;RIT OFF->SEND DDSRX
	
DDSRIT:	MOV	TEMP,TRFLAG
	ANDI	TEMP,$04	;TX FLAG
	CPI	TEMP,$04
	BREQ	DDSTX		;TX DATA SEND
	RJMP	DDSRX		;RX DATA SEND

DDSTX:	LDI	ZL,$0F
	PUSH	ZL
	RCALL	DDSCHK		;DDSCHECK
	POP 	ZL
	BRNE	DDSE		;NOT Z=1 JUMP	
	RJMP	DDS

DDSRX:	LDI	ZL,$0C		;LOOK UP POINT LSB
	PUSH	ZL
	RCALL	DDSCHK
	POP	ZL
	BRNE	DDSE		;NOT Z=1 JUMP	
DDS:	
	RCALL	SDS		;
	LDI	SUB,$21
	CBI	PORTD,0		;STB
	SBI	PORTB,7		;DATA
	SBI	PORTB,6		;SCK
	RCALL	OUTDDS
DDSE:	RJMP	MAIN

;*************** SUBURUTIN ****************
;*** SUBURUTIN DN1M *** SUB,DATA
DN1M:	LDI	SUB,$40		;0F4240H=1MHz:	
	LDI	ZL,$0C
	LD	DATA,Z
	SUB	DATA,SUB
	ST	Z,DATA
	LDI	SUB,$42
	RCALL	DNS
	LDI	SUB,$0F
	RCALL	DNS
	RET

;*** SUBURUTIN DN1M *** SUB,DATA
UP1M:	LDI	SUB,$40		;0F4240H=1MHz:	
	LDI	ZL,$0C
	LD	DATA,Z
	ADD	DATA,SUB
	ST	Z,DATA
	LDI	SUB,$42
	RCALL	UPS
	LDI	SUB,$0F
	RCALL	UPS
	RET

;*** SUBURUTIN DDSCHK *** TEMP,DDS,DATA,SUB
DDSCHK:	MOV	TEMP,ZL
	LDI	DDS,$62
	MOV	ZL,DDS
	LD	DATA,Z
	MOV	ZL,TEMP
	LD	SUB,Z
	CP	DATA,SUB
	BREQ	CHK1		;EQUAL 1ST DATA	
CHKE:	SEZ			;SET Z=1
	RET
CHK1:	DEC	DDS		;2ND
	DEC	TEMP
	MOV	ZL,DDS
	LD	DATA,Z
	MOV	ZL,TEMP
	LD	SUB,Z
	CP	DATA,SUB
	BRNE	CHKE		;NOT EQUAL 2ND DATA
	DEC	DDS		;3RD
	DEC	TEMP
	MOV	ZL,DDS
	LD	DATA,Z
	MOV	ZL,TEMP
	LD	SUB,Z
	CP	DATA,SUB
	BRNE	CHKE		;NOT EQUAL 3RD DATA
	CLZ			;SET Z=0
	RET
;*** SUBURUTIN SEND DATA SAVE SDS*** TEMP,DDS,SUB
SDS:	PUSH	ZL
	MOV	TEMP,ZL
	LDI	DDS,$62
	MOV	ZL,TEMP
	LD	SUB,Z
	MOV	ZL,DDS
	ST	Z,SUB
	DEC	DDS
	DEC	TEMP
	MOV	ZL,TEMP
	LD	SUB,Z
	MOV	ZL,DDS
	ST	Z,SUB
	DEC	DDS
	DEC	TEMP
	MOV	ZL,TEMP
	LD	SUB,Z
	MOV	ZL,DDS
	ST	Z,SUB
	POP	ZL
	RET
	
;*** SUBRUTIN OUTDDS *** DATA,TEMP
OUTDDS:	LDI	DATA,$00		;DUMMY DATA 2BIT+
	RCALL	DOUT
	LD	DATA,Z
	RCALL	DOUT		;DDS LSB 1ST DATA
	DEC	ZL
	LD	DATA,Z
	RCALL	DOUT		;DDS LSB 2ND DATA
	DEC	ZL
	LD	DATA,Z
	RCALL	DOUT		;DDS MSB DATA
	DEC	ZL
				;2BIT ADD
	CBI	PORTB,6		;SCK CLEAR
	CBI	PORTB,7		;DATA CLEAR
	SBI	PORTB,6		;SCK SET
	CBI	PORTB,6		;SCK CLEAR
	CBI	PORTB,7		;DATA CLEAR
	SBI	PORTB,6		;SCK SET
	CBI	PORTB,6		;SCK CLEAR	

	LDI	DATA,$80		;W0
	RCALL	DOUT
	SBI	PORTD,0		;STB PULS
	CBI	PORTD,0
	RET	

DOUT:	LDI	TEMP,$08	;ROTATE COUNTER
DOUT1:	CBI	PORTB,6
	ROR	DATA
	BRCS	SET1		;IF CARRY BIT=1 JUMP 
	CBI	PORTB,7		;CARRY CLEARED
DOUT2:	SBI	PORTB,6
	DEC	TEMP
	BREQ	EOUT		;8BIT END
	RJMP	DOUT1
SET1:	SBI	PORTB,7
	RJMP	DOUT2
EOUT:	RET	

;***SUBURUTIN  dds data up *** DATA,TRFLAG
DDSUP:	LDI	ZL,$0A
	MOV	DATA,TRFLAG	;STEP SET
	ANDI	DATA,$C0
	CPI	DATA,$C0
	BREQ	UP10
	CPI	DATA,$80
	BREQ	UP100
	CPI	DATA,$40
	BREQ	UP1K
	RJMP	UP10K

;*** SUBURUTIN 10/100Hz UP *** SUB,DATA
UP10:	LDI	SUB,$0A		;10->$0A
	RJMP	UP
UP100:	LDI	SUB,$64		;100->$64		
UP:	LDI	ZL,$0C
	LD	DATA,Z
	ADD	DATA,SUB
	ST	Z,DATA
	BRCS	UPA
	RET
UPA:	LDI	SUB,$00
	RCALL	UPS
	BRCS	UPB
	RET
UPB:	RCALL	UPS
	RET

;*** SUBURUTIN UPS *** DATA,SUB
UPS:	DEC	ZL
	LD	DATA,Z
	ADC	DATA,SUB
	ST	Z,DATA
	RET

;*** SUBRUTIN 1/10kHz UP *** SUB,DATA      
UP1K:	LDI	SUB,$E8		;1000->$03E8	
	LDI	ZL,$0C
	LD	DATA,Z
	ADD	DATA,SUB
	ST	Z,DATA
	LDI	SUB,$03
	RCALL	UPS
	LDI	SUB,$00
	BRCS	UPB
	RET

;*** SUBRUTIN 10kHz UP *** SUB,DATA
UP10K:	LDI	SUB,$10		;10000->$2710
	LDI	ZL,$0C
	LD	DATA,Z
	ADD	DATA,SUB
	ST	Z,DATA
	LDI	SUB,$27
	RCALL	UPS
	LDI	SUB,$00
	BRCS	UPB
	RET

;***SUBURUTIN  dds data DOWN *** DATA,TRFLAG
DDSDN:	LDI	ZL,$0A
	MOV	DATA,TRFLAG	;STEP SET
	ANDI	DATA,$C0
	CPI	DATA,$C0
	BREQ	DN10
	CPI	DATA,$80
	BREQ	DN100
	CPI	DATA,$40
	BREQ	DN1K
	RJMP	DN10K

;*** SUBURUTIN 10/100Hz DOWN *** DATA,SUB
DN10:	LDI	SUB,$0A
	RJMP	DN
DN100:	LDI	SUB,$64
DN:	LDI	ZL,$0C
	LD	DATA,Z
	SUB	DATA,SUB
	ST	Z,DATA
	BRCS	DNA
	RET
DNA:	LDI	SUB,$00
	RCALL	DNS
	BRCS	DNB
	RET
DNB:	RCALL	DNS
	RET

;*** SUBURUTIN DNS *** DATA
DNS:	DEC	ZL
	LD	DATA,Z
	SBC	DATA,SUB
	ST	Z,DATA
	RET

;*** SUBRUTIN 1/10kHz DOWN *** DATA,SUB
DN1K:	LDI	SUB,$E8
	LDI	ZL,$0C
	LD	DATA,Z
	SUB	DATA,SUB
	ST	Z,DATA
	LDI	SUB,$03
	RCALL	DNS
	LDI	SUB,$00
	BRCS	DNB
	RET

;*** SUBRUTIN 10kHz DOWN *** DATA,SUB
DN10K:	LDI	SUB,$10
	LDI	ZL,$0C
	LD	DATA,Z
	SUB	DATA,SUB
	ST	Z,DATA
	LDI	SUB,$27
	RCALL	DNS
	LDI	SUB,$00
	BRCS	DNB
	RET

;*** SUBURUTIN DATA UP *** DATA
DUP:	LD	DATA,Z
	INC	DATA
	CPI	DATA,$3A
	BRNE	DUE
	LDI	DATA,$30		;ZERO SET
	ST	Z,DATA
	DEC	ZL
	RJMP	DUE2
DUE:	ST	Z,DATA
	LDI	ZL,$FF
	CLC			;CLEAR CARRY
	RET	
DUE2:	SEC			;SET CARRY
	RET

;*** SUBURUTIN DATA DN *** DATA
DDN:	LD	DATA,Z
	DEC	DATA
	CPI	DATA,$2F
	BRNE	DDE
	LDI	DATA,$39	;NINE SET
	ST	Z,DATA
	DEC	ZL
	RJMP	DDE2
DDE:	ST	Z,DATA
	LDI	ZL,$FF
	CLC			;CLEAR CARRY
	RET
DDE2:	SEC
	RET
	
;*** SUBRUTIN CALL *** DATA
DCALL:	LD	DATA,Z
	RCALL	BUSY
	RCALL	LCD4RO
	RET

;*** SUBRUTIN  COPY R->T *** 
TR:	MOV	AT0,AR0		;COPY T=R
	MOV	AT1,AR1
	MOV	AT2,AR2
	MOV	AT3,AR3
	MOV	AT4,AR4
	MOV	DAT0,DAR0
	MOV	DAT1,DAR1
	MOV	DAT2,DAR2

	RET

;*** SUBRUTIN ILR *** DATA,SUB
ILR:	RCALL	BUSY
	LDI	DATA,$C0	;2GYOUME ADDRESS SET
	RCALL	LCD4SO

	RCALL	BUSY
	LDI	DATA,$4A	;J
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$4A	;J
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$31	;1
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$49	;I
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$4C	;L
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$52	;R
	RCALL	LCD4RO

	RET

;*** SUBRUTIN MS *** DATA,SUB
MS:	RCALL	BUSY
	LDI	DATA,$80	;1GYOUME ADDRESS SET
	RCALL	LCD4SO

	RCALL	BUSY
	LDI	DATA,$4D	;M
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$2F	;/
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$53	;S
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$20	;_
	RCALL	LCD4RO

	RET

;*** SUBRUTIN RT *** DATA,SUB
RT:	RCALL	BUSY
	LDI	DATA,$80	;1GYOUME ADDRESS SET
	RCALL	LCD4SO

	RCALL	BUSY
	LDI	DATA,$52	;R
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$2F	;/
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$54	;T
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$20	;_
	RCALL	LCD4RO

	RET

;*** SUBRUTIN TEN *** DATA
TENS:	RCALL	BUSY
	LDI	DATA,$84	;[50,] ADDRESS SET
	RCALL	LCD4SO

	LDI	DATA,$35	;5
	RCALL	BUSY
	RCALL	LCD4RO

	LDI	DATA,$30	;0
	RCALL	BUSY
	RCALL	LCD4RO
	
	LDI	DATA,$2C	;,
	RCALL	BUSY
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$8A	;[.] ADDRESS SET
	RCALL	LCD4SO

	LDI	DATA,$2E	;.
	RCALL	BUSY
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$8D	;[kHz] ADDRESS SET
	RCALL	LCD4SO

	LDI	DATA,$6B	;k
	RCALL	BUSY
	RCALL	LCD4RO

	LDI	DATA,$48	;H
	RCALL	BUSY
	RCALL	LCD4RO

	LDI	DATA,$7A	;z
	RCALL	BUSY
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$CA	;[.] ADDRESS SET
	RCALL	LCD4SO

	LDI	DATA,$2E	;.
	RCALL	BUSY
	RCALL	LCD4RO

	RCALL	BUSY
	LDI	DATA,$CD	;[kHz] ADDRESS SET
	RCALL	LCD4SO

	LDI	DATA,$6B	;k
	RCALL	BUSY
	RCALL	LCD4RO

	LDI	DATA,$48	;H
	RCALL	BUSY
	RCALL	LCD4RO

	LDI	DATA,$7A	;z
	RCALL	BUSY
	RCALL	LCD4RO

	RET

;***　SUBRUTIN　LCD8SO　*** DATA,
LCD8SO:	CBI	PORTD,5		;RS
	CBI	PORTD,4		;R/W
	SBI	PORTD,6		;E
	OUT	PORTB,DATA
	RCALL	WAIT
	CBI	PORTD,6
	RET			;

;***　SUBRUTIN　LCD4SO　*** DATA,SUB
LCD4SO:	CBI	PORTD,5		;RS
	CBI	PORTD,4		;R/W
	SBI	PORTD,6		;E
	MOV	SUB,DATA	
	ORI	DATA,$0F	
	OUT	PORTB,DATA
	RCALL	WAIT
	CBI	PORTD,6

	CBI	PORTD,5		;RS
	CBI	PORTD,4		;R/W
	SBI	PORTD,6		;E
	SWAP	SUB	
	ORI	SUB,$0F	
	OUT	PORTB,SUB
	RCALL	WAIT
	CBI	PORTD,6

	RET		

;***　SUBRUTIN　LCD4RO　*** DATA,SUB
LCD4RO:	SBI	PORTD,5		;RS
	CBI	PORTD,4		;R/W
	SBI	PORTD,6		;E
	MOV	SUB,DATA	
	ORI	DATA,$0F	
	OUT	PORTB,DATA
	RCALL	WAIT
	CBI	PORTD,6

	SBI	PORTD,5		;RS
	CBI	PORTD,4		;R/W
	SBI	PORTD,6		;E
	SWAP	SUB	
	ORI	SUB,$0F	
	OUT	PORTB,SUB
	RCALL	WAIT
	CBI	PORTD,6

	RET		;

;***　SUBRUTIN　250US　*** SUB
QUS:	CLR	SUB		;250uS WAIT
LOOP1:	NOP			;1/6.144MHz*256*6=250uS
	NOP
	NOP
	NOP
	DEC	SUB
	BRNE	LOOP1	
	RET			

;***　SUBRUTIN　TIMER　*** DATA,SUB
TIMER:	RCALL	QUS
	DEC	DATA
	BRNE	TIMER		
	RET			;

;***　SUBRUTIN　BUSY　*** TEMP
BUSY:	rcall	pinit2
	CBI	PORTD,5		;RS
	SBI	PORTD,4		;R/W
	SBI	PORTD,6		;E
	RCALL	WAIT
LOOP2:	;RJMP	LO
	SBIC	PINB,7		;BUSY FLAG
	RJMP	LOOP2
lo:	CBI	PORTD,6
	rcall	pinit1
	RET			;

;*** SUBRUTION	WAIT ***
WAIT:	RET			;CLK *7=1.14uS

;**** subrution PORTのイニシャライズ **** TEMP
pinit1:					;PORT OUTPUT SET
	; ポートＢの４−８を出力に設定
	ldi	temp,0xF0
	out	DDRB,temp
	; ポートＢの１−４をＰＵＬＬＵＰに設定
	ldi	temp,0x0F
	out	PORTB,temp
	ret

pinit0:	; ポートＤの０，４−６を出力に設定
	ldi	temp,0x71
	out	DDRD,temp
	; ポートＤの１−３をＰＵＬＬＵＰに設定
	ldi	temp,0x0E
	out	PORTD,temp
	ret

;**** subrution PORTのイニシャライズ **** TEMP
pinit2:					;PORT INPUT SET	
	; ポートＢの４−８を入力に設定
	ldi	temp,0x00
	out	DDRB,temp
	; ポートＢの１−8をＰＵＬＬＵＰに設定
	ldi	temp,0xFF
	out	PORTB,temp
	ret

;**** End of File ****

.ESEG
eevar1:	.DB $32,$32,$32,$32,$32,$32,$32,$32	;EEROM CLEAR 2
	.DB $32,$32,$32,$32,$32,$32,$32,$32
	.DB $32,$32,$32,$32,$32,$32,$32,$32
	.DB $32,$32,$32,$32,$32,$32,$32,$32
	.DB $32,$32,$32,$32,$32,$32,$32,$32
	.DB $32,$32,$32,$32,$32,$32,$32,$32
	.DB $32,$32,$32,$32,$32,$32,$32,$32
	.DB $32,$32,$32,$32,$32,$32,$32,$32